int rSize = 1;//ellipseの大きさ
int hNum = 2000;//配列の数
int mFlag = 0;//flag 0=off 1=on
int eCenter;//中心点
int rad = 200;//半径
float angle = 0;//角度

float dx,dy, distance;//距離の座標(dx,dy)と長さ(distance)
float speed = 15;//近づくスピード

float an = 0.1;//angleを変化させる値
float xrad, yrad;//xPos2の中心点からの長さ x軸(xrad) y軸(yrad)

//-----配列-----
float[] xPos1 = new float[hNum];//xPos1のx座標
float[] yPos1 = new float[hNum];//yPos1のy座標
float[] xPos2 = new float[hNum];//xPos2のx座標
float[] yPos2 = new float[hNum];//yPos2のy座標

void setup(){
  size(400, 400);//画面サイズ
  background(255);//背景
  frameRate(30);//フレームレート（秒）
  noStroke();//枠線無し
  smooth();//ズムーズ
  
  eCenter = width/2;//eCenterは中心点
  
  //-----開始位置-----
  for(int i=0; i<hNum; i++){
    xPos1[i] = eCenter;//中心
    yPos1[i] = eCenter;
    xPos2[i] = cos(angle)*rad + eCenter;//円
    yPos2[i] = sin(angle)*rad + eCenter;
    angle += 0.1;//角度を増やす
  }
}

void draw(){
  background(255);//背景塗りつぶし
  for(int i=0; i<hNum; i++){
    fill(0);//塗りつぶし 黒
    ellipse(xPos1[i], yPos1[i], rSize, rSize);//円を描画
  }
  
  //-----徐々に近づく動き-----
  for(int i=0; i<hNum; i++){
    dx = (xPos2[i]-xPos1[i]);//xPos1とxPos2の距離
    dy = (yPos2[i]-yPos1[i]);//yPos1とyPos2の距離
    distance = sqrt(sq(dx)+sq(dy));//ピタゴラスの定理で距離を出す
    if(distance>0){//距離が０より大きい時
      xPos1[i] += dx/speed;//徐々に近づく
      yPos1[i] += dy/speed;
    }
    if(distance<1){//距離が1より小さい時
      mFlag = 1;//Flagがon
      xrad = sin(angle)*200;//sinで値を(-200~200)まで変化させる
      yrad = cos(angle)*100;//cosで値を(-100~100)まで変化させる
    }
  }
  
  //-----Flagがonの時 xPox2の値を決める-----
  if(mFlag==1){
    for(int i=0; i<hNum; i++){
      xPos2[i] = cos(angle)*xrad + eCenter;//xPos2に値を代入
      yPos2[i] = sin(angle)*yrad + eCenter;
      angle += sin(an);//正円描画を崩す
      an += 0.03;//angleの変化する幅
    }
    mFlag = 0;//Flagがoff
  }
}