画像処理サンプル（3d）

ピクセルの色の明るさを、奥行きに変換するプログラムです。

import processing.opengl.*;    //openGLのライブラリをインポート
import processing.video.*;    //ビデオのライブラリをインポート

Capture video;
float angleY = 30.0, angleX = -20.0;

void setup() {
  size(640, 480, OPENGL);
  video = new Capture(this, 80, 60, 60);
  noStroke();
}

void draw() {
  lights();
  background(0);
  //画面中央にオブジェクトがくるように移動する
  translate(width/2, height/2, -200.0);
  //マウスの動きによって角度が変わる。
  angleX = 360.0*((float)mouseY/(float)height)+180.0;
  angleY = 360.0*((float)mouseX/(float)width)+180.0;
  rotateX(radians(angleX));
  rotateY(radians(angleY));

  if (video.available()) {  //もしキャプチャができたら、
    video.read(); //ビデオフレームの読み込み
    video.loadPixels(); //ビデオのピクセルを操作できるようにする

    //1ピクセルごとに色を調べる。
    for (int y = 0; y < video.height; y ++) {
      for (int x = 0; x < video.width; x ++) {
        //ビデオのピクセルを抜き出す
        int pixelColor = video.pixels[y*video.width + x];

        //赤、緑、青をそれぞれ抽出する。以下の3行はビットシフトといって、
        //理解するのが結構大変なので、ここでは詳細は説明しない。
        int r = (pixelColor >> 16) & 0xff;
        int g = (pixelColor >> 8) & 0xff;
        int b = pixelColor & 0xff;

        pushMatrix();    //座標を保存
        translate(x*8-width/2, y*8-height/2, 0.0);        
        fill(r, g, b);    //色を適応させる
        //直方体を作成。手前から奥の長さは、色によって変化する。最大値は300。
        //黒のときに300、白のときに0になる。
        box(7, 7, (float)((255-r)*(255-g)*(255-b))/pow(255.0, 3)*300.0);
        popMatrix();    //座標を復帰
      }
    }
  }
}