画像処理サンプル（effect_line）

線状のエフェクトをかけるサンプルです。

/*
This program has been arranged by Yasushi Noguchi.
Original Code was created by Golan Levin. 
*/

import processing.video.*;

Capture video;

void setup() {
  size(640, 480);
  
  //80 x 60のキャプチャ画像を生成
  video = new Capture(this, 80, 60, 50);
  video.start();  //Processing ver.2.0以上はこのコードが必要
  loadPixels();    //画面に画像のピクセルを展開
  rectMode(CENTER);
  noFill();
}

void draw() {
  if (video.available()) {  //もしキャプチャができたら、
    video.read(); //ビデオフレームの読み込み
    video.loadPixels(); //ビデオのピクセルを操作できるようにする
  background(0);  //ver.2.0以上はここにbackgroundが必要

    //1ピクセルごとに色を調べる。
    for (int y = 0; y < video.height; y ++) {
      for (int x = 0; x < video.width; x ++) {
        //ビデオのピクセルを抜き出す
        int pixelColor = video.pixels[y*video.width + x];

        //赤、緑、青をそれぞれ抽出する。以下の3行はビットシフトといって、
        //理解するのが結構大変なので、ここでは詳細は説明しない。
        int r = (pixelColor >> 16) & 0xff;
        int g = (pixelColor >> 8 ) & 0xff;
        int b = pixelColor & 0xff;
        
        float lineSize = (float)(r + g + b)/24.0;
        stroke(r, g, b);
        line(x*8+random(-3, 3)-lineSize/2, y*8+random(-3, 3), 
             x*8+random(-3, 3)+lineSize/2, y*8+random(-3, 3));
    }
    }
  }
}